anyone having problems with munging core lvl in windows 10 ?

[wsa30h]

does anyone have a solution for localization not munging in windows 10 ?

[Anyder]

I think someone posted the solution to that in the forums already! Make sure you search before posting

Let us know if you can't find it, otherwise! Good luck

[wsa30h]

thanks anyrider but i cant find it.

[SleepKiller]

I haven't tested this extensively but it should work.

Open up "BFBuilder/Data/MergeLocalize.bat" in a text editor and replace it's contents with this. (Or make the same edits I have manually.) Instead of using "more" (which iirc is what causes problems) for merging localization it'll use PowerShell's "Get-Content" command. The end result should be identical, I think.

Code Select Expand

@echo off


:: //-----------------------------------------------------------
:: // Create some cleaner variable names
:: //-----------------------------------------------------------

if "%3"=="" (
ECHO.
Echo Format: .\MergeLocalize.Bat InputDir1 inputDir2 TempDir
ECHO.
GOTO DONE
)

set Source1Dir=%1
set Source2Dir=%2
set TempDir=%3


:: //-----------------------------------------------------------
:: // Copy and merge the two text files for each language
:: //-----------------------------------------------------------

if NOT EXIST %TempDir% mkdir %TempDir%

setlocal ENABLEDELAYEDEXPANSION


:: Make sure PowerShell is on the path.
SET PATH="%SYSTEMROOT%"\System32\WindowsPowerShell\v1.0\;%PATH%

FOR %%i IN (%Source1Dir%\*.cfg %Source2Dir%\*.cfg) DO (
echo Merging %%i...

:: Use "Get-Content" from PowerShell instead of "more".
powershell -Command Get-Content %%i >>  %TempDir%\%%~ni%%~xi
)

ECHO.

:DONE

[wsa30h]

thanks sleep killer that works.